/*Implementation von Adjektiven in eine Grammatik mit Semantik
*/


satz(Sem_Satz) -->
           np(lambda(Sem_Verb,Sem_Satz)),
           vp(Sem_Verb).


np(Sem) --> en(Sem).

%n durch ap ersetzt
np(Sem_Np) --> art(lambda(Sem_Ap,Sem_Np)),
               ap(Sem_Ap).

%ap kann einfach ein Nomen sein
ap(Sem) --> n(Sem).

%Kombiniere Adjektivsemantik mit Nominalsemantik durch "und"
ap(lambda(X,und(PAdj,PNom))) -->
                      adj(lambda(X,PAdj)),
                      n(lambda(X,PNom)).

%Unverändert
vp(Sem) --> vi(Sem).
vp(lambda(Y,Sem)) -->
         vt(lambda(X,lambda(Y,P))),
         np(lambda(lambda(X,P),Sem)).

%Lexikon
art(lambda(lambda(X,P),lambda(lambda(X,Q),ex(X,und(P,Q)))))
         --> [ein].


%Adjektiv ist ein einstelliges Prädikat (wie Nomina und intransitive Verben)
adj(lambda(X,blau(X)))          --> [blaues].



en(lambda(lambda(herschel,P),P)) --> [herschel].

n(lambda(X,kind(X)))             --> [kind].
n(lambda(X,gestirn(X)))          --> [gestirn].


vi(lambda(X,lachen(X)))         --> [lacht].
vt(lambda(X,lambda(Y,entdecken(Y,X))))
                                --> [entdeckt].