% Dieser Syntaxregel entspricht die folgende Bildungsregel der Prädikatenlogik:
% Wenn A eine Individuenkonstante ist und B ein einstelliges Prädikat,
% dann ist B(A) eine Formel

satz(Formel) --> en(IndividuenKonstante), 
                 vi(Praedikat), 
                 {Formel =..[Praedikat,IndividuenKonstante]}.

% Wenn A und C Individuenkonstanten sind und B ein einstelliges Prädikat
% dann ist B(A,C) eine Formel

satz(Formel) --> en(IndividuenKonstante1), 
                 vt(Praedikat),
                 en(IndividuenKonstante2), 
                 {Formel =..[Praedikat,IndividuenKonstante1,IndividuenKonstante2]}.
                 
% Entsprechungen:
%SPRACHE           PRÄDIKATENLOGIK
%Satz              Formel
%Eigenname         Individuenkonstante
%N-stelliges Verb  N-stelliges Prädikat
       
en(herschel)  --> [herschel].
en(uranus)    --> [uranus].
vi(leuchten)  --> [leuchtet].
vt(umkreisen) --> [umkreist].
           

%Grammatikvariante mit VP
% Entsprechende Logikregel:
% Wenn A eine Individuenkonstante ist und B ein einstelliges Prädikat,
% dann ist B(A) eine Formel

satz_mit_vp(Formel) -->
                 en(IndividuenKonstante1),
                 vp(Praedikat1),
                 {Praedikat1 =..[Praedikat|Argumente]},
                 {Formel =..[Praedikat,IndividuenKonstante1|Argumente]}.


% Wenn B ein zweistelliges Prädikat ist und A eine Individuenkonstante, 
% dann ist B(A) ein einstelliges Prädikat
               
vp(Praedikat1) -->
                 vt(Praedikat2), 
                 en(IndividuenKonstante),
                 {Praedikat1 =..[Praedikat2,IndividuenKonstante]}.

vp(Praedikat) -->
                 vi(Praedikat).